UOS 마고서버 광부매크로<수정> > UOS 매크로

본매크로는 UOS 마이닝 매크로로 스캐빈저 없이 진행합니다.

* 기초적으로 캐릭터는 인간으로 생성 메저리 100 , 팅커스킬 100 이 필요하며 마이닝0부터해도 100까지 금방 올라갑니다.

* 캐릭의 스탯은 힘 125로 설정하여 최대한 많은 무게를 갖도록합니다.

* 마이닝을 위해 아래 매크로는 펠루카 광산 룬북 4권이 필요합니다 2권으로 줄이실분은 매크로를 수정하시면됩니다.*

* 집으로 리콜 시 오어를 보관할 상자와 보석을 보관할상자 근처에 있어야 하므로 집앞계단에 상자를 배치하시고 그 앞에 리콜이 되도록 셋팅해주세요*

* 첫 실행시 아래와 같이 설정해주시면됩니다.*

** 시작시 오어상자에 잉갓 300개와 백팩에 팅커툴1개가 있어야 합니다. **

1. 'Ore Storage' =>마이닝으로 캔 광물을 보관할 상자입니다.

2. 'gem box' =>광물채집시 나오는 보석을 보관할 상자입니다 오어스토리지와 같은 상자를 클릭하셔도 무관합니다.

3. 'Ore1' ~ 4는 룬북책을 선택합니다 아틀란티스 룬북은 안됩니다.

4.    if weight > '480'  캐릭의 최대 무게가 550은 되어야 480정도 설정하시는겁니다

<마이닝 속도가 매우빠르며 480을 인식하고 리콜하는 사이에도 한두개의 오어를 더 캐 결국 520되는 경우가 많습니다.>

removelist 'Runes'

removelist 'OreBook'

@clearjournal

pause 200

if not @findalias 'Ore Storage'

  headmsg 'Select the storage'

  promptalias 'Ore Storage'

endif

if not @findalias 'gem box'

  headmsg 'Select the gem box'

  promptalias 'gem box'

endif

if not @findobject 'Ore1'

  promptalias 'Ore1'

endif

if not @findobject 'Ore2'

  promptalias 'Ore2'

endif

if not @findobject 'Ore3'

  promptalias 'Ore3'

endif

if not @findobject 'Ore4'

  promptalias 'Ore4'

endif

if not @findobject 'Home'

  headmsg 'Select the home book'

  promptalias 'Home'

endif

if not listexists 'OreBook'

  createlist 'OreBook'

endif

if list 'OreBook' == 0

  @pushlist 'OreBook' 'Ore1'

  @pushlist 'OreBook' 'Ore2'

  @pushlist 'OreBook' 'Ore3'

  @pushlist 'OreBook' 'Ore4'

endif

if not listexists 'ore'

  createlist 'ore'

  @pushlist 'ore' 0x19b9

  @pushlist 'ore' 0x19ba

  @pushlist 'ore' 0x19b8

  @pushlist 'ore' 0x19b7

endif

if not listexists 'gem'

  createlist 'gem'

  @pushlist 'gem' 0xf25

  @pushlist 'gem' 0xf10

  @pushlist 'gem' 0xf21

  @pushlist 'gem' 0xf19

  @pushlist 'gem' 0xf15

  @pushlist 'gem' 0xf2d

  @pushlist 'gem' 0xf16

  @pushlist 'gem' 0xf13

  @pushlist 'gem' 0xf26

  @pushlist 'gem' 0x3197

  @pushlist 'gem' 0x3195

  @pushlist 'gem' 0x3198

  @pushlist 'gem' 0x3193

  @pushlist 'gem' 0x3192

  @pushlist 'gem' 0x3194

  @pushlist 'gem' 0xf28

endif

if not listexists 'Runes'

  createlist 'Runes'

endif

if list 'Runes' == 0

  @pushlist 'Runes' 50

  @pushlist 'Runes' 51

  @pushlist 'Runes' 52

  @pushlist 'Runes' 53

  @pushlist 'Runes' 54

  @pushlist 'Runes' 55

  @pushlist 'Runes' 56

  @pushlist 'Runes' 57

  @pushlist 'Runes' 58

  @pushlist 'Runes' 59

  @pushlist 'Runes' 60

  @pushlist 'Runes' 61

  @pushlist 'Runes' 62

  @pushlist 'Runes' 63

  @pushlist 'Runes' 64

  @pushlist 'Runes' 65

endif

for 0 to OreBook

  for 0 to 'Runes'

    @clearjournal

    pause 500

    @useobject OreBook[]

    waitforgump 0x59 5000

    replygump 0x59 Runes[]

    pause 1500

    if @injournal 'blocked' 'system'

      clearjournal

      replay

    endif

    if mana < 30

      headmsg 'Need mana'

      useskill 'meditation'

      while mana < 40

      endwhile

    endif

    // check ingot, shovel, tinker tool and then dig

    while not @injournal 'There is no metal here to mine' 'system'

      pause 300

      if counttype 0x1bf2 0 'backpack' < 10

        pause 500

        useobject 'Home'

        waitforgump 0x59 5000

        replygump 0x59 50

        pause 3500

        useobject 'Ore Storage'

        pause 1000

        movetype 0x1bf2   'Ore Storage' 'backpack' [(0 0 0)] '0' 100

        pause 500

        useobject OreBook[]

        waitforgump 0x59 5000

        replygump 0x59 Runes[]

        pause 1500

      endif

      if counttype 0x1eb8 0 'backpack' < 2

        usetype 0x1eb8  'backpack'

        waitforgump 0x38920abd 15000

        replygump 0x38920abd 15

        waitforgump 0x38920abd 15000

        replygump 0x38920abd 23

        waitforgump 0x38920abd 15000

        pause 100

      endif

      if not @findtype 0xf39 0 'backpack'

        usetype 0x1eb8 0 'backpack'

        waitforgump 0x38920abd 15000

        replygump 0x38920abd 15

        waitforgump 0x38920abd 15000

        replygump 0x38920abd 72

        waitforgump 0x38920abd 15000

        pause 100

      endif

      canceltarget

      @usetype '0xf39' '0' 'backpack'

      waitfortarget 5000

      targettileoffset -1 1 0

      pause 700

      if @injournal "You can't mine" "system" "target"

        headmsg 'wrong spot'

        poplist 'Runes' 'front'

        break

      endif

      // go home

      if weight > '480'

        pause 500

        useobject 'Home'

        waitforgump 0x59 5000

        replygump 0x59 50

        pause 3000

        for 0 to 'ore'

          while @findtype ore[] 'any' 'backpack'

            moveitem 'found' 'Ore Storage'

            pause 1050

          endwhile

        endfor

        for 0 to 'gem'

          while @findtype gem[] 'any' 'backpack'

            moveitem 'found' 'gem box'

            pause 1050

          endwhile

        endfor

        //recall back

        useobject OreBook[]

        waitforgump 0x59 5000

        replygump 0x59 Runes[]

        pause 1500

      endif

    endwhile

  endfor

  poplist 'Runes' 'front'

endfor

if not timerexists 'shownames'

  createtimer 'shownames'

endif

if not timerexists 'instruments'

  createtimer 'instruments'

endif